Arduino

Buy | Download | Getting Started | Learning | Reference | Hardware | FAQ

Blog » | Forum » | Playground »

Reference Language (extended) | Libraries | Comparison | Board

## shiftOut(dataPin, clockPin, bitOrder, value)

#### Description

Shifts out a byte of data one bit at a time. Starts from either the most (i.e. the leftmost) or least (rightmost) significant bit. Each bit is written in turn to the dataPin, after which the clockPin is toggled to indicate that the bit is available.

This is known as synchronous serial protocol and is a common way that microcontrollers communicate with sensors, and with other microcontrollers. The two devices always stay synchronized, and communicate at close to maximum speeds, since they both share the same clock line.

#### Parameters

dataPin: the pin on which to output each bit (int)

clockPin: the pin to toggle once the dataPin has been set to the correct value (int)

bitOrder: which order to shift out the bits; either MSBFIRST or LSBFIRST.
(Most Significant Bit First, or, Least Significant Bit First)

value: the data to shift out. (byte)

#### Returns

None

#### Note

The dataPin and clockPin must already be configured as outputs by a call to pinMode.

#### Example

For accompanying circuit, see the tutorial on controlling a 74HC595 shift register.

    //**************************************************************//
    //  Name    : shiftOutCode, Hello World                         //
    //  Author  : Carlyn Maw,Tom Igoe                               //
    //  Date    : 25 Oct, 2006                                      //
    //  Version : 1.0                                               //
    //  Notes   : Code for using a 74HC595 Shift Register           //
    //          : to count from 0 to 255                            //
    //****************************************************************

    //Pin connected to ST_CP of 74HC595
    int latchPin = 8;
    //Pin connected to SH_CP of 74HC595
    int clockPin = 12;
    ////Pin connected to DS of 74HC595
    int dataPin = 11;

    void setup() {
      //set pins to output because they are addressed in the main loop
      pinMode(latchPin, OUTPUT);
      pinMode(clockPin, OUTPUT);
      pinMode(dataPin, OUTPUT);
    }

    void loop() {
      //count up routine
      for (int j = 0; j < 256; j++) {
        //ground latchPin and hold low for as long as you are transmitting
        digitalWrite(latchPin, LOW);
        shiftOut(dataPin, clockPin, LSBFIRST, j);
        //return the latch pin high to signal chip that it
        //no longer needs to listen for information
        digitalWrite(latchPin, HIGH);
        delay(1000);
      }
    }

### Note

Note that this function, as it is currently written, is hard-wired to output 8 bits at a time. An int holds two bytes (16 bits), so outputting an int with shiftout requires a two-step operation:

#### Example:

    int data;
    int clock;
    int cs;
    ...

    digitalWrite(cs, LOW);
    data = 500;
    shiftOut(data, clock, MSBFIRST, data)
    digitalWrite(cs, HIGH);

    // this will actually only output 244 because
    // 500 % 256 = 244
    // since only the low 8 bits are output

    // Instead do this for MSBFIRST serial
    data = 500;
    // shift out highbyte
    // " >> " is bitshift operator - moves top 8 bits (high byte) into low byte
    shiftOut(data, clock, MSBFIRST, (data >> 8));

    // shift out lowbyte
    shiftOut(data, clock, MSBFIRST, data);

    // And do this for LSBFIRST serial
    data = 500;
    // shift out lowbyte
    shiftOut(data, clock, LSBFIRST, data);

    // shift out highbyte
    shiftOut(data, clock, LSBFIRST, (data >> 8));

Reference Home

Reference Home

Corrections, suggestions, and new documentation should be posted to the Forum.

The text of the Arduino reference is licensed under a Creative Commons Attribution-ShareAlike 3.0 License. Code samples in the reference are released into the public domain.

Edit Page | Page History | Printable View | All Recent Site Changes